Hello! I'm fairly new to the Apple II community. I just purchased an Apple IIc locally, but it did not come with anything but the unit itself, so I'm in the process of starting from scratch gathering peripherals or making my own. My hardest struggle is figuring out a solution for a mouse to use.
The original AppleMouse II is hard to come by and ebay listings are a bit unreasonable. $50 is what I spent on this IIc after all. So I've set out to find/make an adapter to use a mostly modern PS/2 mouse to interface with the 9 pin AppleMouse jack.
I've researched the schematics and pinouts and determined it should be pretty straight forward to translate PS/2 data to the quadrature mechanics used by the original mouse design. I'm even using this posting as the fundamental structure, using an Arduino for the conversion:
https://danceswithferrets.org/geekblog/?p=742
After modifying the code a little for the correct pinouts for the apple connector and connecting a PS/2 mouse, the conversion works!
Unfortunately, where I am stumped at is when this adapter gets plugged in to the IIc. At first when the adapter was plugged into the port, the IIc would turn on to it's home screen but I could not get into AppleSoft BASIC. After probing around the adapter, I unplugged the mouse trigger pin and then the IIc acted normally, booting into BASIC and all. The digital pin for the mouse switch was active high, so I changed it to low and that seems to fixed it. Correct me if I am wrong, but I believe the switch is to be low by default and then voltage applied when pressed?
None the less, I still can't seem to "test" the mouse to see if it's working. I've tried a few basic programs for testing the mouse by drawing on the screen or displaying the XY values, but none of them seem to work for me. I would love to see this project succeed since it might be of some help to others who might want to adapter a modern mouse to their Apple II! I plan on sharing the Arduino code and my process once I work out the kinks.
Does anyone have any thoughts on what might be holding me up? Is the Arduino code for the quadrature conversion the correct method? Is there a better way to test a mouse input on the Apple II or a better way to acknowledge it's being read by the machine? Some help is greatly appreciated!
See the topic "What is the MOUSE ID pin?".
The button input is grounded when pressed, like all other switch inputs on all devices and computers.
Just to clarify, the MOUSE ID (pin 1) is always hardwired to ground when the mouse is plugged in. It doesn’t matter if the mouse button is pressed or not.
Thanks for the feedback. I'll go ahead and switch that pin back to high on the arduino then since it seems that was correct after all. I do also have the MOUSE ID pin going to ground.
Something must be wrong on the computer side of things then. With everything connected properly on the mouse side, when I turn the IIc on I get the main Apple IIc "Check Disk Drive" screen, but if I press control+reset it wont boot BASIC, it'll just keep going to the main screen.
The machine will do that if it thinks joystick button 0 (pin 7) is being held down at reset. (Joystick button 0 maps to the Open-Apple key on the keyboard, and that key controls the reset behavior).
But the machine should be seeing it as a mouse, right? That's what the MOUSEID pin tied to ground is for?
When the IIc is on with the adapter plugged in, I get about 4.3V on pin 7, and if I press and hold the mouse switch it goes down to 0. This is the correct behavior for any mouse to have, is it not?
My guess is the port decides whether or not a mouse or a joystick is plugged in is determined by pin 1. If it's tied to ground, it's a mouse, but if it's tied to a joystick button with about 5V, it's a joystick. That's just a guess though. Every schematic shows the MOUSEID just tied to pin 3 and getting grounded.
I'm concerned about the voltages to and from the port being too low. Pin 2 (5V) is only 4.8V, pin 7 (MSW) is around 4.3 V- 4.4V. If I plugged the arduino into USB for power instead, the values are a bit higher but the IIc recieves a bit of power as well, enough to turn on the power LED, which is concerning of backfeeding.
Someone was selling if I remember right a PIC based adapter to allow a USB mouse to plug into a //c or a //e Apple Mouse card. Probably would work on a Mac that uses a 9 pin mouse too. I bought a couple of them. I don't remember if there was a GitHub project for DIYers or not. I'd have to search around to find into on them.
Yes, I am aware of that product, as well as a PIC based PS/2 to Apple Mouse adapter. I would buy one of those in a heartbeat, but it appears they are not making them any more.
Plus, an arduino is easier to obtain and program, so it would be great if I could add this project to the community for anyone else who desires such a thing. I dont need to make money off of this thing, I just want a workable Apple II mouse, haha.
EDIT: I think I found what you were talking about, I'm surprised this result didnt come up for me earlier:
https://www.applefritter.com/content/a2usb-apple-ii-usb-mouse-interface-card-emulation
I may have to see if I could adapt it to the IIc so it wouldn't require an expansion port. I'm also not too familiar with Picos.
That wasn't what I was talking about. The device I am talking about is much smaller and has a DE9 that plugs into the //c mouse/game port or a //e Mouse Interface Card and it has a USB port that you can plug a normal USB mouse into.
Here is one, but this isn't even the one I was talking about, just a similar product:
https://www.tindie.com/products/option8/usb-mouse-interface-for-apple-ii-beta/
I finally found it... this is what I was talking about...
https://www.applefritter.com/content/usb-apple-c-c-and-apple-bus-mouse-card-adapter
I PMed that user imediately, haha. Thank you for finding that. That's the best alternative option I've seen so far.
I'm still surprised there isnt much in terms of Arduino support for this kind of adapter though. It feels like I'm so close to figuring it out, if I could just tell if the adapter is interfacing properly.
Here's the Arduino files if anyone want's to have a look. Again, they are based on this article which was to adapter a ps/2 mouse to an Acorn Archimedes: http://danceswithferrets.org/geekblog/?p=742
I turned on the Serial.print functions to read if the mouse movement and switch were working, and everything looks good, it turns a PS/2 data and clock signal into a quadrature output out if the digital pins to the DE9 connector on an Apple.
The joystick button 0 connects pin 7 to 5V, whereas the mouse button connects pin 7 to ground.
On my IIc I'm reading about 3.1 V across pins 7 and 3 when the mouse is connected; 0 V when the button is down..
Ok, good to know! Based on what you said in your previous reply, it seems like my IIc is not reading the adapter as a mouse but a joystick?
Is it possible there are different GND rails for each ground pin? I've had pin 1 and 3 all going to the GND pins on the Arduino.
I'm using this one on a IIe.
https://www.tinkerboy.xyz/product/tinkerboy-usb-mouse-to-mac-converter-adapter-for-macintosh-with-db9-mouse-port/
Haven't tried it out on a IIc
Pins 1 and 3 are shorted together on a real mouse.
Just a guess, but perhaps the voltage you're seeing on pin 7 (4.4 V) is too high and is being read as a Joystick Button press by the machine.
You're probably right, I have a little update on things:
Doing some more research, I realized I probably needed to simulate an open drain output from the switch pin. This article explains things better, but I think since the mouse and joystick are shared on the same port for the IIc, the logic needs to be handled differently.
https://mirrors.apple2.org.za/ground.icaen.uiowa.edu/MiscInfo/Hardware/mouse.iic
So I came by some Arduino code that makes an open drain or open collector output by switching the output settings when a switch is pressed:
void openDrain(byte pin, bool value)
{ if(value) pinMode(pin, INPUT);
else pinMode(pin, OUTPUT);
digitalWrite(pin, LOW);
}
So now the switch pin outputs 3.1V and when the mouse switch is pressed goes down to 0V. Well, almost, it goes down to .5V, but I'm not sure if this is an issue. But so far I have all the right pinout and Apple BASIC runs normally. I just need to figure out the test code for getting the mouse to do something on screen. Like I said before, any type of basic code I try as a mouse test doesnt seem to do anything, I always just get a black screen.
You can use the following Basic program to draw with the mouse on the screen. First copy it into the clipboard and use <Shift><Insert> in AppleWin to paste and run it, so you can see what it does.
1 REM **********************
2 REM * MOUSE.SKETCH *
3 REM * BY SANDY MOSSBERG *
4 REM * COPYRIGHT (C) 1985 *
5 REM * BY MICROSPARC, INC *
6 REM * CONCORD, MA 01742 *
7 REM **********************
100 REM ********************************
110 REM * VARIABLE USAGE: *
120 REM * X = HORIZONTAL COORDINATE *
130 REM * Y = VERTICAL COORDINATE *
140 REM * OX = PRIOR X VALUE *
150 REM * OY = PRIOR Y VALUE *
160 REM * C = COLOR AT X,Y *
170 REM * S = STATUS OF MOUSE BUTTON *
180 REM * N = SLOT OF MOUSE FIRMWARE *
190 REM ********************************
200 :
210 GOSUB 710: REM TEST FOR MOUSE FIRMWARE
220 GOSUB 620: REM INITIALIZE
230 PRINT D$"IN#"N: REM GET INPUT FROM MOUSE
240 REM ====================
250 REM TRACK PATH OF MOUSE:
260 REM ====================
270 GOSUB 390: REM GET MOUSE POSITION DATA
280 IF PEEK (49249) >= 128 OR PEEK (49250) >= 128 THEN IF S < 3 THEN C = 0: COLOR=0: GOTO 330: REM IF MOUSE BUTTON DOWN AND OPEN/CLOSED-APPLE PRESSED, CLEAR POINT ON SCREEN (SET COLOR TO BLACK)
290 IF OX <> X OR OY <> Y THEN IF S >= 2 THEN COLOR= C: PLOT OX,OY:C = SCRN(X,Y): REM IF MOUSE POSITION HAS CHANGED. CLEAR PRIOR CURSOR AND READ NEW SCREEN COORDINATE
300 IF S < 0 THEN 460: REM PROCESS KEYPRESS
310 IF S <= 2 THEN COLOR = 15:C = 15: GOTO 330: REM IF MOUSE BUTTON DOWN, SET COLOR TO WHITE
320 COLOR = 1: REM CURSOR COLOR IS MAGENTA (H ATCHED BOX)
330 PLOT X,Y: REM PUT COLOR ON SCREEN
340 OX = X:OY = Y: REM CURRENT COORDINATES NO W OLD HAT
350 GOTO 270: REM LOOP BACK FOR MORE INPUT
360 REM ===================
370 REM OBTAIN MOUSE INPUT:
380 REM ===================
390 INPUT "";X,Y,S: REM READ MOUSE DATA
400 X = INT (X / 25.575): REM CONVERT MOUSE POSITION HORIZONTAL COORDINATES (0-1023) TO LORES COORDINATES (0-40)
410 Y = INT (Y / 25.575): REM SAME FOR VERTICAL COORDINATES
420 RETURN
430 REM =====================
440 REM CHECK KEYBOARD INPUT:
450 REM =====================
460 POKE -16368,0: REM CLEAR KEYBOARD STROBE
470 PRINT D$"IN#0": REM ACCEPT INPUT FROM KEYBOARD
480 VTAB 22: PRINT "PRESS RETURN TO CONTINUE, ESC TO QUIT OR CTL-C TO CLEAR SCREEN ";: GET A$: REM PROMPT TO CONTINUE, QUIT OR CLEAR SCREEN
490 PRINT: IF A$ = CHR$ (3) THEN 220: REM CLEAR SCREEN IF CTL-C PRESSED
500 IF A$ = CHR$ (13) THEN HOME : PRINT D$"IN#"N : GOTO 270: REM CONTINUE IF RETURN PRESSED
510 IF A$ <> CHR$ (27) THEN PRINT CHR$ (7): GOTO 480: REM TRAP ERRONEOUS KEYPRESS
520 REM =====
530 REM QUIT:
540 REM =====
550 TEXT : HOME
560 PRINT D$"PR#"N: PRINT CHR$ (0): REM DEACTIVATE MOUSE
570 PRINT D$"PR#0": REM SEND OUTPUT TO SCREEN
580 PRINT "THE MOUSE IS SLEEPING...": END
590 REM ============================
600 REM INITIALIZE SCREEN AND MOUSE:
610 REM ============================
620 HOME : GR : REM CLEAR SCREEN AND SET LORES
630 D$ = CHR$ (4): REM DEFINE DOS STRING. FOR DOS 3.3 USE D$=CHR$(13)+CHR$(4) D$ = CHR$ (4)
640 C = 0: REM STARTING POINT BLANK
650 PRINT D$"PR#"N: PRINT CHR$ (1): REM ACTIVATE MOUSE
660 PRINT D$"PR#0": REM SEND OUTPUT TO SCREEN
670 RETURN
680 REM ==========================
690 REM SEARCH FOR MOUSE FIRMWARE:
700 REM ==========================
710 L1 = 49420:L2 = 49659: REM START WITH SLOT 1 MOUSE FIRMWARE ID BYTES (L1=$C10C, L2=$C1FB)
720 FOR I = 1 TO 7: REM TEST SLOTS 1-7
730 IF PEEK (L1) = 32 AND PEEK (L2) = 214 THEN N = I : I = 9: REM IF MOUSE FIRMWARE LOCATED, N=SLOT # AND I > 8 FLAGS THE MATCH
740 L1 = L1 + 256:L2 = L2 + 256: REM SET FOR NEXT HIGHER SLOT
750 NEXT I
760 IF I > 8 THEN RETURN : REM MOUSE FIRMWARE FOUND
770 POP : PRINT CHR$ (7);: PRINT "MOUSE FIRMWARE NOT FOUND...": REM MOUSE FIRMWARE NOT LOCATED
Thank you! It helped running it in an emulator first, then I could copy the program to a virtual disk and try it on the real hardware!
I also got a disk image of MousePaint to work off of virtual disk, and sure enough, everything is working! This Arduino adapter is getting closer to a success!
So the mouse works, but the movement can be a bit laggy and sporadic. One of the reasons for this might be that the Arduino is running at too fast of a clock speed for reading the quadrature movements than what the IIc can take, so I'm going to figure out how to delay the sensor reading in the code. I'm learning a bit about how everything works as I do this, so it's a lot of back and forth. I did find more documentation on how others have designed their quadrature formulas for their own adapter designs.
Would it have been easier just to buy an adapter someone has already designed? Definitely yes, if I can source one still being sold. But this was a decent way to use spare parts I had on hand to build something just to see if it was worth it! I'm a graphic designer, so to see a program such as MousePaint running on an old Apple II when I've been so accustomed to things like Adobe Photoshop is really a treat!
I'll get the Arduino code a bit more perfected and then make another post with all of the details. This should also work really easily with a USB mouse since most USB mice can work in a "PS/2 mode" if they cant communicate with a modern driver. The PS/2 port side of things should be the same, just using USB +Data and -Data wires for the Data and Clock. (I have an older beige mouse that matched the color of the IIc almost perfectly, so using PS/2 was mostly for aesthetic.)
One of the USB->9 pin Apple mouse adapters looks like it probably uses and Atmel 328P which is what is on some of the Arduino boards like the Uno. The Dan ][ card also uses that. It is possible to build a dedicated board with the Atmel microcontroller and a couple discrete parts (capacitors and oscillator crystal) to avoid needing an entire Arduino board. There are SMD versions of the Atmel processors which lend themselves to mass builds more than through hole DIP versions, but the latter are better for DIY builds for most people.
It's getting harder and harder to find USB mice that also support PS/2. Most of the older wired ones support both PS/2 and USB, so you just need a simple adapter. However the newer wireless ones don't. I am glad I kept my old Microsoft wired USB mouse from 15 years ago, because last year I needed a PS/2 mouse and I was able to use it.
I have been able to get actual PS/2 (with the Mini DIN type connector) mice by ordering through Amazon here in the US. You can also often find used ones cheap on eBay. I don't know what availability is like in Europe.
You can find PS/2 mice in Europe easily used, but they are often in a very sorry shape. Also they are useless and just take up space unless you need a PS/2 mouse. The USB ones that also support PS/2 on the other hand you can still use on a modern PC and the tiny adapter doesn’t take much space:
ESP32 FabGL.JPG
That was my post. I have //c mouse USB to quadrature adapters available. At VCFMW I had a group of Lisa owners using them on their displays.
https://www.8bitdevices.com/product/apple-c-usb-mouse-adapter/
Ignore the "out of stock" notice. The store checkout is disabled while I change providers. If someone wants one, PM me here and I'll manually ship one out.
Here's where I am at with this project if anyone wants to download the latest arduino files:
The UNO is just so fast at translating the data I had to up the delays to try slowing it down so the Apple II could register movements easier. I've tried it out on MousePaint and it works pretty well, just tends to make a abstract movement if you move the mouse too fast. I'm starting to not like the code the orignal maker used for decoding movement into quadrature. It's a bit too complicated for what it needs to be. If I redid everything from scratch, I would follow this guys video for reference instead:
https://www.youtube.com/watch?v=Qszv5GzYDNc&list=LL&index=3&t=863s
The old mice have lower resolution, so the speed of the pulses they produce is lower than a mouse from the 21st century (whether it uses a PS/2 or USB interface doesn't matter).
A typical resolution for an early 1980s mouse is 100 "dpi" or counts/inch. You can buy mice today that advertise 14,400 "dpi" or even higher.
This is the reason your converter makes the cursor jump erratically. It has nothing to do with the processor speed of the microcontroller you are using. A real quadrature mouse changes its outputs effectively instantly. But its repetitive pulse rate is proportional to the speed the user moves the mouse, which won't be any faster than 60"/s even if he jerks it back and forth like a ferret on meth.
In reality the necessary speed is less than half that, so let's use 30"/s. The old mouse won't pulse any faster than
100 counts/in • 30 in/s = 3000 pulses/s,
or about 3 pulses each millisecond. Your converter won't, either, if you properly divide the coordinate changes coming from the modern mouse to an equivalent of 100 counts/inch.
That is one of the issues with the A2USB card when paired with a modern optical USB mouse: it is super sensitive. All original Apple II mice move the X or Y coordinate by 100 per inch. The modern optical USB mice move by around 1000 per inch!