5 DIM Z(9): DIM C(8): DIM ME$(8): PX$="wth": CB$="}"
9 ? CHR$(4);"IN#4"
10 JS$ = ""
20 GET A$
30 JS$ = JS$ + A$
40 IF A$ = CB$ THEN GOSUB 1000
50 GOTO 20
60 END

1000 IF MID$(JS$,3,3) <> PX$ THEN GOTO 10
1015 C = LEN(JS$)-9
1020 E$ = RIGHT$(JS$,C): B = LEN(E$)-2: RE$ = LEFT$(E$,B)
1106 X = 0:TMP$ = RE$
1110 FOR I = 1 TO  LEN(RE$)
1120 IF MID$ (RE$,I,1) = ","  THEN  GOSUB 2000
1122 NEXT I
1140 GOSUB 2500


1141 REM #### READ MEASUREMENTS IN ARRAY #####

1142 FOR D = 0 TO 15: READ T$
1143 IF D => 8 THEN ME$(D-8)=T$
1144 NEXT: RESTORE

1145 HOME : FOR Q = 0 TO 7: READ LB$
1146 VTAB Q+1: ? LB$ +": ": VTAB Q+1: HTAB 20: ? Z(Q): VTAB Q+1: HTAB 27: ? ME$(Q)
1148 NEXT
1149 RESTORE
1160 VTAB 11: ? "WAITING FOR DATA ... "
1150 JS$ = "" : REM ERASE STRING VAR
1170 RETURN

1999 REM #### DO SOME INCREMENTS ########

2000 C(X)=I
2005 X=X+1
2010 RETURN

2498 REM #### PROCESS STRING SLICES #####

2500 Z(0) =  VAL( MID$ (RE$,1,C(0)-1))
2510 Z(1) =  VAL( MID$ (RE$,C(0)+1,C(1)-C(0)-1))
2520 Z(2) =  VAL( MID$ (RE$,C(1)+1,C(2)-C(1)-1))
2530 Z(3) =  VAL( MID$ (RE$,C(2)+1,C(3)-C(2)-1))
2540 Z(4) =  VAL( MID$ (RE$,C(3)+1,C(4)-C(3)-1))
2550 Z(5) =  VAL( MID$ (RE$,C(4)+1,C(5)-C(4)-1))
2560 Z(6) =  VAL( MID$ (RE$,C(5)+1,C(6)-C(5) -1))
2570 Z(7) =  VAL( MID$ (RE$,C(6)+1, LEN(RE$)-C(6)))
2590 RETURN

3000 DATA "TEMPERATURE","PRESSURE","HUMIDITY","WIND DIRECTION","WIND SPEED","WIND GUST","RAINFALL","BATTERY"
3010 DATA "C","HPA","%","-","m/s","m/s","mm","V"